10 REM *************************************
15 REM *         ASCENT.BAS                *
20 REM * Ascent Rate Calculation (6/21/93) *
25 REM *     by Bill Brown WB8ELK          *
30 REM *************************************
40 CLS
45 INPUT "Balloon Weight (gms).: ";BW
50 INPUT "Nozzle Lift (lbs.): ";NL
60 INPUT "Payload Weight (lbs.):";PW
70 INPUT "Parachute Weight (ozs.): ";PA
80 INPUT "Radar Reflector Weight (ozs.): ";RW
90 K=142:REM ** Factor for 300-1500 gram balloons **
110 PW=PW*454
120 PA=(PA/16)*454
130 RW=(RW/16)*454
140 NL=NL*454
150 FL = NL-(PA+PW+RW)
160 GL = FL+BW+PW+PA+RW
170 GOSUB 1000:REM ** CR is cube root of GL returned from subroutine **
180 AR = 142*((SQR(FL))/CR):REM ** Ascent Rate of balloon system **
185 PRINT ""
190 PRINT AR*3.28083;" ft/min ascent rate":REM ** Ascent Rate of balloon **
195 PRINT ""
200 GOTO 45
1000 REM ** Cube Root Subroutine **
1005 QQ=GL
1010 FOR Z=1 TO 100
1020 ZF=Z*Z*Z
1030 IF ZF>QQ THEN GOTO 1050
1040 NEXT Z
1050 Z1=Z-1
1060 Z2=Z1*Z1*Z1
1070 IF Z2>QQ THEN GOTO 1100
1080 Z1=Z1+.1
1090 GOTO 1060
1100 Z2=Z1-.1
1110 Z3=Z2*Z2*Z2
1120 IF Z3>QQ THEN GOTO 1150
1130 Z2=Z2+.01
1140 GOTO 1110
1150 Z3=Z2-.01
1160 Z4=Z3*Z3*Z3
1170 IF Z4>QQ THEN GOTO 1200
1180 Z3=Z3+.001
1190 GOTO 1160
1200 Z4=Z3-.001
1210 Z5=Z4*Z4*Z4
1220 IF Z5>QQ THEN GOTO 1250
1230 Z4=Z4+.0001
1240 GOTO 1210
1250 CR=Z4-.0001
1290 RETURN